ServiceStack.Java/src/AndroidClient/client/build.gradle at expose-status-code · danim1236/ServiceStack.Java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
apply plugin: 'com.android.library'
apply plugin: 'com.github.dcendents.android-maven'
apply plugin: 'com.jfrog.bintray'

version = "1.0.10"
group = "net.servicestack"                                        // Maven Group ID for the artifact
String packageId = "client"

android {
    compileSdkVersion 21
    buildToolsVersion "21.1.2"

    defaultConfig {
        minSdkVersion 15
        targetSdkVersion 21
        versionCode 1
        versionName version
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

Properties properties = new Properties()
properties.load(project.file('./local.properties').newDataInputStream())

def siteUrl = 'https://github.com/ServiceStack/ServiceStack.Java'      // Homepage URL of the library
def gitUrl = 'https://github.com/ServiceStack/ServiceStack.Java.git'   // Git repository URL

bintray {
    user = properties.getProperty("bintray.user")
    key = properties.getProperty("bintray.apiKey")

    configurations = ['archives']
    pkg {
        repo = "maven"
        userOrg = 'servicestack'
        name = "ServiceStack.Client"
        websiteUrl = siteUrl
        vcsUrl = gitUrl
        licenses = ["BSD 3-Clause"]
        publish = true
    }
}

task makeJar(type: Copy) {
    from('build/intermediates/bundles/release/')
    into('build/libs/')
    include('classes.jar')
    rename ('classes.jar', packageId + '-' + version + '.jar')
}

install {
    repositories.mavenInstaller {
        // This generates POM.xml with proper parameters
        pom {
            project {
                packaging 'jar'

                // Add your description here
                name 'ServiceStack.Client'
                description 'A client library to call your ServiceStack webservices.'
                url siteUrl

                // Set your license
                licenses {
                    license {
                        name 'The BSD 3-Clause License'
                        url 'https://raw.githubusercontent.com/ServiceStack/Assets/master/docs/license/LICENSE-BSD3.txt'
                    }
                }

                developers {
                    developer {
                        id 'mythz'
                        name 'Demis Bellot'
                        email 'team@servicestack.net'
                    }
                    developer {
                        id 'layoric'
                        name 'Darren Reid'
                        email 'team@servicestack.net'
                    }
                }
                scm {
                    connection 'https://github.com/ServiceStack/ServiceStack.Java'
                    developerConnection 'https://github.com/ServiceStack/ServiceStack.Java'
                    url 'https://github.com/ServiceStack/ServiceStack.Java'
                }
            }
        }
    }
}.dependsOn makeJar

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.google.code.gson:gson:2.3.1'
}

task sourcesJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier = 'sources'
}

task javadoc(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task clearJar(type: Delete) {
    delete ("build/libs/" + packageId + '-' + version + '.jar')
}

artifacts {
    archives javadocJar
    archives sourcesJar
    archives file: new File('build/libs/' + packageId + '-' + version + '.jar'), name: packageId, type: 'jar'
}

task findConventions << {
    println project.getConvention()
}